* fichier : g_rotation_tuyauterie_droite_1.dgibi
****************************************************
****************************************************
* *
* VERIFICATION DE LA PROCEDURE G_THETA *
* POUR LE CALCUL DE G POUR UNE FISSURE *
* DANS UNE SECTION DE TUYAU DROIT *
* - *
* COMPARAISON ENTRE LE RESULTAT 3D *
* AVEC ET SANS LES OPTIONS 'POINT_1' ET 'POINT_2' *
* ET UNE SOLUTION ANALYTIQUE. ON EN PROFITE *
* POUR TESTER EGALEMENT L'UTILISATION DE *
* L'INDICE 'NOEUDS_AVANCES'. *
* *
* SOLUTION ANALYTIQUE TIREE DE : *
* "THE STRESS ANALYSIS OF CRACKS HANDBOOK" *
* TADA, PARIS AND IRWIN (2000) *
* *
****************************************************
* I - OPTIONS ET DONNEES
* ----------------------
* OPTIONS
OPTI 'DIME' 3 'ELEM' 'CUB8' ;
* SI BTRAC = VRAI ON TRACE LE MAILLAGE
BTRAC = FAUX ;
* DONNEES
* RCYL = RAYON
* ECYL = EPAISSEUR
* LCYL = LONGUEUR
* ANG1 = SECTEUR ANGULAIRE DE LA FISSURE
RCYL = 350. ;
ECYL = RCYL/10. ;
LCYL = 3000. ;
ANG1 = 45. ;
* PROPRIÉTÉS MATÉRIAU
MYOU = 2.E5 ;
POI = 0.3 ;
* II - MAILLAGE
* -------------
* PARAMETRES DU MAILLAGE
DENS1 = ECYL / 5. ;
DENS DENS1 ;
PREC1 = DENS1 * 1.E-10 ;
* MAILLAGE RAYONNANT AUTOUR DE LA POINTE DE FISSURE
LF = RCYL * ANG1 / 180. * PI ;
RRAY = LF / 6. ;
PF = 0. 0. 0. ;
P1 = RRAY 0. 0. ;
D1 = DROI 5 PF P1 ;
S1 = D1 ROTA 8 180. PF (PF PLUS (0. 0. 1.)) ;
X Y = (COOR 1 S1) (COOR 2 S1) ;
R = ((X**2) + (Y**2))**0.5 ;
PELIM = R POIN 'MINI' ;
ELIM PELIM PREC1 ;
S1 = REGE S1 ;
* PASSAGE EN RECTANGLE
CON1 = CONT S1 ;
PCER = R POIN 'MAXI' ;
CER1 = CON1 ELEM 'APPUYE' PCER ;
NEL = (NBEL CER1) / 4 ;
XP = RRAY * 1.5 ;
XN = 0. - XP ;
REC1 = DROI NEL (XP 0. 0.) (XP XP 0.) ;
REC1 = DROI (2 * NEL) REC1 (XN XP 0.) ;
REC1 = DROI NEL REC1 (XN 0. 0.) ;
S2 = CER1 REGL 2 REC1 ;
STOT = S1 ET S2 ;
* EXTENSION JUSQU'AU BORT DU CYLINDRE (COTE FISSURE)
REC2 = REC1 hom*o (LF / XP) (0. 0. 0.) ;
S3 = REC1 REGL REC2 ;
STOT = STOT ET S3 ;
* EXTENSION JUSQU'AU BORD DU CYLINDRE (COTE LIGAMENT)
XMIN = MINI (COOR 1 REC2) ;
XMAX = MAXI (COOR 1 REC2) ;
PGAU = REC2 POIN 'DROI' (XMIN 0. 0.) (XMIN 1. 0.) ;
DGAU = REC2 ELEM 'APPUYE' PGAU ;
S4 = DGAU TRAN 'DFIN' (RCYL / 3.) ((XMAX - XMIN - (RCYL * PI)) 0. 0.) ;
STOT = STOT ET S4 ;
* EXTENSION SUR LA LONGUEUR DU CYLINDRE
Y = COOR 2 STOT ;
YMAX = MAXI Y ;
PHAU = STOT POIN 'DROI' (0. YMAX 0.) (1. YMAX 0.) ;
DHAU = (CONT STOT) ELEM 'APPUYE' PHAU ;
S5 = DHAU TRAN 'DFIN' (LCYL / 5) (0. (LCYL - YMAX) 0.) ;
STOT = STOT ET S5 ;
* EXTRUSION DANS L'EPAISSEUR
VTOT = STOT VOLU 10 'TRAN' (0. 0. ECYL) ;
* DEFINITION DE LA FISSURE ET DU FRONT
PPLAN = VTOT POIN 'PLAN' (0. 0. 0.) (1. 0. 0.) (0. 0. 1.) ;
PFIS = (COOR 1 PPLAN) POIN 'EGSUPE' 0. ;
ENVTOT = ENVE VTOT ;
LVSUP = ENVTOT ELEM 'APPUYE' PFIS ;
LVSUP = LVSUP COUL 'ROUG' ;
PFRO = PFIS POIN 'DROI' (0. 0. 0.) (0. 0. 1.) ;
FRO1 = (CONT LVSUP) ELEM 'APPUYE' PFRO ;
FRO1 = (ORDO FRO1) COUL 'BLEU' ;
VTRAC = VTOT ET LVSUP ET FRO1 ;
* TRANSFORMATION EN CYLINDRE ;
XMIN = MINI (COOR 1 VTOT) ;
DEPL VTOT 'MOIN' (XMIN 0. (ECYL / 2.)) ;
X1 Y1 Z1 = COOR VTRAC ;
THET1 = (X1 / RCYL) * 180. / PI ;
THET1 = 180. - THET1 ;
R1 = RCYL + Z1 ;
X2 = R1 * (COS THET1) ;
Y2 = Y1 ;
Z2 = R1 * (SIN THET1) ;
UDEP = (NOMC 'UX' (X2 - X1)) + (NOMC 'UY' (Y2 - Y1)) + (NOMC 'UZ' (Z2 - Z1)) ;
DEPL VTOT 'PLUS' UDEP ;
SI BTRAC ;
TRAC 'CACH' VTRAC ;
FINSI ;
* III - MODELE, MATERIAU, CLS ET RESOLUTION
* -----------------------------------------
* MODELE ET MATERIAU
MOD1 = MODE VTOT 'MECANIQUE' 'ELASTIQUE' ;
MAT1 = MATE MOD1 'YOUN' MYOU 'NU' POI ;
RIG1 = RIGI MAT1 MOD1 ;
* CONDITIONS AUX LIMITES ET CHARGEMENT
SPLAN = ENVTOT ELEM 'APPUYE' PPLAN ;
SLIG = DIFF SPLAN LVSUP ;
BLO1 = BLOQ 'UY' SLIG ;
PBAS = VTOT POIN 'PLAN' (0. 0. 0.) (1. 0. 0.) (0. 1. 0.) ;
BLO2 = BLOQ 'UZ' PBAS ;
BLO0 = BLO1 ET BLO2 ;
PEXT = VTOT POIN 'PLAN' (0. LCYL 0.) (1. LCYL 0.) (0. LCYL 1.) ;
SEXT = ENVTOT ELEM 'APPUYE' PEXT ;
F0 = PRES 'MASS' MOD1 -1. SEXT ;
* RESOLUTION
U0 = RESO (RIG1 ET BLO0) F0 ;
SI BTRAC ;
DEF0 = DEFO VTRAC U0 0. ;
DEF1 = DEFO VTRAC U0 'ROUG' ;
TRAC 'CACH' (DEF0 ET DEF1) ;
FINSI ;
* IV - POST-TRAITEMENT
* --------------------
* APPEL A G_THETA
SUPTAB = TABL ;
SUPTAB.'OBJECTIF' = MOT 'J' ;
SUPTAB.'LEVRE_SUPERIEURE' = LVSUP ;
SUPTAB.'FRONT_FISSURE' = FRO1 ;
SUPTAB.'MODELE' = MOD1 ;
SUPTAB.'CARACTERISTIQUES' = MAT1 ;
SUPTAB.'SOLUTION_RESO' = U0 ;
SUPTAB.'CHARGEMENTS_MECANIQUES' = F0 ;
SUPTAB.'COUCHE' = 10 ;
NOAV = FRO1 ELEM 'COMPRIS' (FRO1 POIN 2) (FRO1 POIN ((NBNO FRO1) - 1)) ;
SUPTAB.'NOEUDS_AVANCES' = NOAV ;
SUPSANS = COPI SUPTAB ;
SUPTAB.'POINT_1' = (0. 1. 0.) ;
SUPTAB.'POINT_2' = (0. 0. 0.) ;
SUPAVEC = COPI SUPTAB ;
G_THETA SUPAVEC ;
GAVEC = SUPAVEC.'RESULTATS' ;
G_THETA SUPSANS ;
GSANS = SUPSANS.'RESULTATS' ;
* SOLUTION ANALYTIQUE
ANG2 = ANG1 / 180. ;
FDETH = 1. + (7.5 * (ANG2**1.5)) - (15. * (ANG2**2.5)) + (33. * (ANG2**3.5)) ;
GANA = (1.-(POI**2)) / MYOU * PI * LF * (FDETH**2.) ;
LIST GANA ;
* COMPARAISON
GCHPO1 = SUPAVEC.'CHPO_RESULTATS' ;
EVO1 = EXTR (EVOL 'CHPO' GCHPO1 NOAV) 'COUR' 1 ;
GCHPO2 = SUPSANS.'CHPO_RESULTATS' ;
EVO2 = EXTR (EVOL 'CHPO' GCHPO2 NOAV) 'COUR' 1 ;
EVO3 = (EVO1 / EVO1) * GANA ;
SI BTRAC ;
DESS (EVO1 ET EVO2 ET EVO3) ;
FINSI ;
ERRAVEC = (INTG ((EVO1 - EVO3)**2))**0.5 ;
ERRSANS = (INTG ((EVO2 - EVO3)**2))**0.5 ;
CRI1 = (INTG EVO3 'ABS') * 3.E-2 ;
MESS 'ERREUR SUR LE CALCUL DE G AVEC POINT_1 ET POIN_2 :' ERRAVEC ;
MESS 'ERREUR SUR LE CALCUL DE G SANS POINT_1 ET POIN_2 :' ERRSANS ;
SI (ERRAVEC > CRI1) ;
MESS 'ERREUR : L''ERREUR SUR G DEPASSE LE CRITERE' ;
ERRE 5 ;
FINSI ;
SI (ERRAVEC > ERRSANS) ;
MESS 'ERREUR : L''ERREUR SUR G AVEC POINT_1 ET POIN_2 EST' ;
MESS ' SUPERIEURE A L''ERREUR SANS CES OPTIONS' ;
ERRE 5 ;
FINSI ;
FIN ;
